***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 20, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJE8408-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     108.8
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=5.855   VTO=0.78  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=1.5e10  gamma=0.12)
Rd     d1    d2    195m  TC=3.9m,2u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=22  TBV1=5.525e-4 TBV2=6.525e-7 CJO=6.144e-12  M=2.958e-1  VJ=3.905e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D( IS=5.713e-9 N=1.401 RS=12.04u EG=0.9  TT=20n IKF=2.976e-2)
Rdiode  d1  21    5.819e-2 TC=3m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.396e-11
.MODEL     DGD    D(M=6.026e-1  CJO=4.396e-11   VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.018e-11
.ENDS
*$
